Sub SetToolbar()

'Deklaracja
Dim cbMyToolbar As CommandBar
Dim cbtMyButton As CommandBarButton

Dim cbToolbar As CommandBar
Dim cbtButton As CommandBarButton

Dim bToolbarExists As Boolean, bButtonExists As Boolean

bToolbarExists = False: bButtonExists = False

'Nazwa makra podpietego do przycisku
'oraz nazwa paska narzedzi
Const strNazwaMakra = "nazwa_makra"
Const strToolbarName = "nazwa_paska"
Const strButtonLabel = "Etykieta przycisku"

'Sprawdzanie czy pasek narzedzi i przycisk istnieja
For Each cbToolbar In Application.CommandBars
    If cbToolbar.Name = strToolbarName Then
        bToolbarExists = True
        For Each cbtButton In Application.CommandBars(strToolbarName).Controls
            If cbtButton.Caption = strButtonLabel Then bButtonExists = True
        Next cbtButton
    End If
Next cbToolbar

If bToolbarExists Then
    Set cbMyToolbar = Application.CommandBars(strToolbarName)
Else
    'dodawanie paska narzedzi
    Set cbMyToolbar = Application.CommandBars.Add(strToolbarName)
    cbMyToolbar.Position = msoBarTop
End If
    
'Pasek narzedzi widoczny po wlaczeniu makra
cbMyToolbar.Visible = True


If Not bButtonExists Then
    'dodawanie przycisku
    Set cbtMyButton = cbMyToolbar.Controls.Add(Type:=msoControlButton)
    cbtMyButton.DescriptionText = strButtonLabel
    cbtMyButton.Caption = strButtonLabel
    cbtMyButton.OnAction = strNazwaMakra
    cbtMyButton.Style = msoButtonCaption
End If

Set cbMyToolbar = Nothing
Set cbtMyButton = Nothing

End Sub